...amiért  már  ide  is  beevett  a fene, de nem tudtam megállni szó nélkül.  A
"MR.CODER"  rovat  teljes  egészében  READYSOFT  parcellája,  semmi  esetre sem
kívánom a szálakat az okoskodásommal összekuszálni, de szeretnék valamit időben
tisztázni.   Az  senki  előtt nem titok, hogy a demozás legfontosabb területe a
programozás,   így   minden  bizonnyal  ennek  a  rovatnak  van  a   legnagyobb
olvasótábora, jelentősége a DD-ben.  Ennek megfelelő súlyt szeretnék adni neki,
azonban  hozzáértés  híján  csupán  annyit  tehetek,  hogy  "korlátlan"  helyet
biztosítok számára.  A DEMO-DEPO szerkesztésénél továbbra is elsőbbséget élvez,
amit  READYSOFT  nem  "használt  el",  azzal  gazdálkodnak  a többiek.  Mint az
assembly  nyelvet  ugató  egyén  nagy  érdeklődéssel  olvasgatom én is, azonban
valamit  nagyon  hiányolok:   A  KÉRDÉSEITEKET !!!  Egy ici-picit önzők vagytok
(nem  csak  a  válaszboríték  hiánya miatt, bár a KASOGI és a PUNK család nincs
rokoni  kapcsolatban  egymással),  mindenki  felteszi  a maga kérdését, aztán a
kapott   konccal   elrohan   jó   messze,  hogy  a  többiek   ne   is   lássák.
Szerencsésebbnek  tartanám  ha  rágnátok  Józsi  fülét,  hogy  a  DEMO-DEPO-ban
válaszoljon,  ezzel  később  jutnátok  hozzá, az igaz, de legalább a többiek is
tanulnának  belőle.   Én  például  azt  csináltam, hogy a forráslistát betöltve
átrágtam  rajta  magam, aztán ahol nem volt világos, oda beszúrtam egy kérdést.
Ezt  a  szöveg  file-t  elküldtem,  így  READYSOFT-nak  sem  kell  a   kérdések
bepötyögésével kínlódnia, azonnal nyomathatta a választ, íme:

*****************************************
*??????????
* A csillagokat miért nem veszi szintaktikus hibának???
*  -A csillag vagy a pontosvessző utáni részt a sorban nem veszi figyelembe
*   a fordító, így lehet megjegyzéseket írni a listába.
----------
OldOpenLibrary:	equ	-408
*??????????
* Mi az EQU utasítás?
* Mi a -408?
*  -Az equ utasítással értéket adhatsz egy szimbólumnak, amire később
*   hivatkozhatsz.
*  -A -408 az OldOpenLibrary nevü ROM-rutin belépési címének offszetje
*   az ExecBase-hez képest.
----------
	move.l	#pic,d0		; az első bittérkép címe d0-ban
*??????????
* A #,vagyis a "hashmark" az itt mit jelent?
* A PIC címkében nem a RAW formátumú kép van? A d0-ás adatregiszterben hogy
* fér el egy egész kép?
*  -A # konstans értéket jelöl, jelen esetben a pic címét és NEM az egész      
*   képet !  Lásd `68000 technika és programozás` 150. oldalát ! (utolsó bek.)
*   Nem a pic címkében van a kép, hanem a pic címke értéke megegyezik a kép
*   memóriabeli címével.  Ezt a címet tette bele a d0 regiszterbe.
----------  
        lea	bpls,a0		; ide írja be a címeket
*??????????
* A BPLS cimkét nem kell definiálni?
*  -A bpls címke definiálva van a copperlistánál.   ( bpls: )
----------
	moveq	#4,d7		; 4+1=5 cím beírása
cikl1:	move.w	d0,6(a0)	; a cím alsó word-jét írja be
	swap	d0		; felcseréli a két word-öt
	move.w	d0,2(a0)	; és beírja a felsőt is,
	swap	d0		; majd visszacseréli
*??????????
* Miért szükséges a wordokat cserélgetni? Ezzel a résszel mit csinálsz?
*  -A copperlistában meg kell adni a bittérképek címét. Ez így néz ki :
*   dc.w	$e0,"a cím felső word-je",$e2,"a cím alsó wordje"
*   Egy lépésben nem lehet az egész címet beírni, mivel az alsó és a felső
*   word között van egy copper utasítás ($e2).
*   Ezért az első lépésben beírom az alsó word-öt a copperlistába, majd
*   a regiszterben felcserélem őket. Így a felső alulra kerül, így ezt is
*   be tudom írni egy word-művelettel.
*   Azért kell a csere, mert a word-művelet mindig a regiszter legalsó
*   wordjével történik (ugyanígy a byte művelet) !!!
----------
	move.l	#copper,$dff080	; copper start
*??????????
* A dff080 az melyik copper-utasítás??
*  -$dff080 a COP1LCH címe, tehát a copperlista címét tartalmazza.
*   Ha ide a saját copperlistám címét írom, akkor az fut.
----------
; A copper lista :
;
copper:	dc.w	$1001,$fffe
colors:	dc.w	$180,0,$182,0,$184,0,$186,0,$188,0,$18a,0,$18c,0,$18e,0
	dc.w	$190,0,$192,0,$194,0,$196,0,$198,0,$19a,0,$19c,0,$19e,0
	dc.w	$1a0,0,$1a2,0,$1a4,0,$1a6,0,$1a8,0,$1aa,0,$1ac,0,$1ae,0
	dc.w	$1b0,0,$1b2,0,$1b4,0,$1b6,0,$1b8,0,$1ba,0,$1bc,0,$1be,0
	dc.w	$8e,$2c81,$90,$2cc1,$92,$38,$94,$d0
bpls:	dc.w	$e0,0,$e2,0,$e4,0,$e6,0,$e8,0,$ea,0,$ec,0,$ee,0
	dc.w	$f0,0,$f2,0
	dc.w	$100,$5200,$ffff,$fffe
*??????????
* Azt írtad, hogy a COPPER-lista WAIT, MOVE....  utasításokból áll,
itt nem látok ilyet. Ezt az adathalmazt hogy kell értelmezni????
*	$1001,$fffe	WAIT $10,$01		vár (nem feltétlenül kell)
*	$0180,$0000	MOVE #0,COLOR0		a 0. színregiszter beállítása
*						ugyanez $01be -ig.
*  A színek azért kellenek, nem ?
*	$008e,$2c81	MOVE #$2c81,DIWSTRT	a display ablak bal felső és
*	$0090,$2cc1	MOVE #$2cc1,DIWSTOP	jobb alsó sarkának koord.-ja
*  Meg kell adni, hogy mekkora legyen a megjelenített kép mérete
*	$0092,$0038	MOVE #$38,DDFSTRT	az adatbehozatal kezdete
*	$0094,$00d0	MOVE #$d0,DDFSTOP	az adatbehozatal vége
*  Meg kell adni, hogy melyik pozíciótól kezdje el olvasni a kép-memóriát
*	$00e0,$0000	MOVE #0,BPL1PTH		a bittérkép-cím felső wordje
*	$00e2,$0000	MOVE #0,BPL1PTL		a bittérkép-cím alsó wordje
*						a többi bittérképre ugyenígy
*  Most már azt is tudja, hogy honnan vegye a képet
*	$0100,$5200	MOVE #$5200,BPLCON0	a képernyőformátum
*  Itt meg kell adni a bittérképek számát, a felbontást és a képernyőmódot
*	$ffff,$fffe	WAIT $ff,$ff
*  A copper vége, itt olyan pozícióra vár, amelyik sohasem következik be.
----------

Ilyen egyszerű a dolog. Ne féljetek a nyilvános kérdésektől, senki
nem fog lelamerezni benneteket, és a többieknek is segíthettek ezzel!!!!!

FRICFORCE from FI-RE Crew

