*****************************************
* Demo v1.0 				*
*  code by Readysoft from FI-RE Crew	*
*****************************************
OldOpenLibrary:	equ	-408
;
; A bittérképek címeit beírja a copperlistába :
;
	move.l	#pic,d0		; az elsö bittérkép címe d0-ban
	lea	bpls,a0		; ide írja be a címeket
	moveq	#4,d7		; 4+1=5 cím beírása
cikl1:	move.w	d0,6(a0)	; a cím alsó word-jét írja be
	swap	d0		; felcseréli a két word-öt
	move.w	d0,2(a0)	; és beírja a felsöt is,
	swap	d0		; majd visszacseréli
	add.l	#10240,d0	; a következö bittérkép 10240 byte-al
	addq.l	#8,a0		; nagyobb címen van (40*256 byte)
	dbf	d7,cikl1	; ha van még, jön a következö
;
; A színeket is beírja a copperbe :
;
	lea	cmap,a0		; a paletta címe
	lea	colors+2,a1	; ide kell beírni
	moveq	#31,d7		; 31+1=32 szín
cikl2:	move.w	(a0)+,(a1)	; beírja a szín kódját
	addq.l	#4,a1		; a következö színt 4 byte-al magasabb
	dbf	d7,cikl2	; címre írja
;
; Indítja a coppert :
;
	move.l	#copper,$dff080	; copper start
	move.w	#$0020,$dff096	; lekapcsolja a sprite-okat
;
; Vár a bal egérgombra :
;
wait:	btst	#6,$bfe001
	bne.s	wait
;
; Visszaállítja az eredeti (CLI) képet :
;
	lea	gfx,a1		; graphics.library
	move.l	4,a6		; execbase
	jsr	OldOpenLibrary(a6)
	move.l	38(a0),$dff080	; az eredeti copper cím a gfxbase 38-as
	move.w	#$8020,$dff096	; ofszetjén van, majd sprites off
	rts			; kilépés

gfx:	dc.b	'graphics.library',0,0
;
; A copper lista :
;
copper:	dc.w	$1001,$fffe
colors:	dc.w	$180,0,$182,0,$184,0,$186,0,$188,0,$18a,0,$18c,0,$18e,0
	dc.w	$190,0,$192,0,$194,0,$196,0,$198,0,$19a,0,$19c,0,$19e,0
	dc.w	$1a0,0,$1a2,0,$1a4,0,$1a6,0,$1a8,0,$1aa,0,$1ac,0,$1ae,0
	dc.w	$1b0,0,$1b2,0,$1b4,0,$1b6,0,$1b8,0,$1ba,0,$1bc,0,$1be,0
	dc.w	$8e,$2c81,$90,$2cc1,$92,$38,$94,$d0
bpls:	dc.w	$e0,0,$e2,0,$e4,0,$e6,0,$e8,0,$ea,0,$ec,0,$ee,0
	dc.w	$f0,0,$f2,0
	dc.w	$100,$5200,$ffff,$fffe
;
; Hely foglalás a képnek és a palettának :
;
pic:	blk.b	51200,0
cmap:	blk.b	64,0
